Technology
Stefan Damian, Leave a Comment on The best script to update No-IP DNS
,

The best script to update No-IP DNS

This script was designed to utilize the No-IP Update API which offers direct access to No-IP’s DNS update system. This is the fixed version running on 6.x RouterOs version.

1. Create a new script named no-ip_ddns_update

The following permissions are required for this script to run:

  • write
  • test
  • read

2. Paste the source code that appears below. Edit the user, password, hostname and interface info to match your setup.

# -----------------------------------------------------------------------------------

# No-IP User account info
:local noipuser "<user or email>"
:local noippass "<password>"

# Set the hostname or label of network to be updated.
# Hostnames with spaces are unsupported. Replace the value in the quotations below with your host names.
# To specify multiple hosts, separate them with commas.
:local noiphost "<FQN hostname>"

# Change to the name of interface that gets the dynamic IP address
:local inetinterface "<internet interface>"

#------------------------------------------------------------------------------------
# No more changes need

:global previousIP

:if ([/interface get $inetinterface value-name=running]) do={
# Get the current IP on the interface
   :local currentIP [/ip address get [find interface="$inetinterface" disabled=no] address]

# Strip the net mask off the IP address
   :for i from=( [:len $currentIP] - 1) to=0 do={
       :if ( [:pick $currentIP $i] = "/") do={
           :set currentIP [:pick $currentIP 0 $i]
       }
   }

# Get your previous IP address
   :set previousIP [:resolve $noiphost]
   
   :if ($currentIP != $previousIP) do={
       :log info "No-IP: Current IP $currentIP is not equal to previous IP $previousIP, update needed"
       :set previousIP $currentIP

# The update URL. Note the "\3F" is hex for question mark (?). Required since ? is a special character in commands.
       :local url "http://dynupdate.no-ip.com/nic/update\3Fmyip=$currentIP"
       :local noiphostarray
       :set noiphostarray [:toarray $noiphost]
       :foreach host in=$noiphostarray do={
           :log info "No-IP: Sending update for $host"
           /tool fetch url=($url . "&hostname=$host") user=$noipuser password=$noippass mode=http keep-result=no;
           :log info "No-IP: Host $host updated on No-IP with IP $currentIP"
       }
   }  else={
       :log info "No-IP: Previous IP $previousIP is equal to current IP, no update needed"
   }
} else={
   :log info "No-IP: $inetinterface is not currently running, so therefore will not update."
}

# --------------------------------------------------------------------------------------

3. Create a new scheduler entry to run this script every 5 mins.

system scheduler add comment="Update No-IP DDNS" disabled=no interval=5m name=no-ip_ddns_update \
on-event=no-ip_ddns_update policy=read,write,test

Leave a Reply